Doc produitsMenu

Découverte de métadonnées disponibles

Vous pensez peut-être qu'il est souvent difficile d'identifier les métadonnées disponibles dans les documents indexés. Cette rubrique explique comment utiliser le script de post-conversion AllFieldValues afin de vous aider à extraire et évaluer toutes les métadonnées qui sont disponibles dans les documents d'un référentiel.

Pour trouver des métadonnées disponibles

  1. Faites en sorte que le script de post-conversion AllFieldValues soit disponible pour CES (Coveo Enterprise Search) :

    1. Enregistrez le contenu du script suivant dans le fichier texte [Index_Path]\Scripts\Postconversion-allfieldvalues.txt dans le serveur principal de Coveo.

      '**************************************************************************** 
      ' This postconversion script sample adds a new metadata named 
      ' "AllFieldValues". This new metadata contains the name, the value and the 
      ' type of all document metadata. 
      '**************************************************************************** 
      Option Explicit 
      
      ' A double quote. 
      Dim DOUBLE_QUOTE: DOUBLE_QUOTE = chr(34) 
      
      ' This buffer variable holds all metadata names and values. 
      Dim allValues: allValues = "<AllFieldValues>" & vbNewLine 
      
      ' A collection of all field names. 
      Dim fieldNames: fieldNames = DocumentInfo.Fields 
      
      ' For each document field name. 
      Dim fieldName 
      For Each fieldName In fieldNames 
        ' Get the field value. 
        Dim fieldValue: fieldValue = DocumentInfo.GetFieldValue(CStr(fieldName)) 
        
        ' Add the metadata name and its value to the buffer variable. 
        allValues = allValues & "<Field" 
        allValues = allValues & " name=" & DOUBLE_QUOTE & CStr(fieldName) & DOUBLE_QUOTE 
        allValues = allValues & " value=" & DOUBLE_QUOTE & fieldValue & DOUBLE_QUOTE 
        allValues = allValues & " type=" & DOUBLE_QUOTE & TypeName(fieldValue) & DOUBLE_QUOTE 
        allValues = allValues & " />" & vbNewLine 
      Next 
      
      ' Add the new metadata. 
      Call DocumentInfo.SetFieldValue("AllFieldValues", allValues & "</AllFieldValues>" & vbNewLine)
    2. Ajoutez le script de post-conversion dans l'Outil d'administration à l'aide des valeurs suivantes (voir Ajout d'un script de post-conversion):

      • NomAllFieldValues

      • Fichier de script[Index_Path]\Scripts\Postconversion-allfieldvalues.txt

      • Langage de script : VBScript

  2. Associez le script de post-conversion AllFieldValues à la source dont vous souhaitez voir toutes les métadonnées disponibles (voir Application d'un script de conversion source).

  3. Ajoutez le champ personnalisé AllFieldValues au groupe de champs qu'utilise la source :

    1. Si nécessaire, créez un nouveau groupe de champs qui sera utilisé par cette source (voir Ajout d'un groupe de champs).

    2. Ajoutez le champ personnalisé AllFieldValues au bon groupe de champs à l'aide des valeurs suivantes (voir Ajout ou modification de champs personnalisés).

      • NomAllFieldValues

      • Type : Chaîne

      • Nom des métadonnéesAllFieldValues

    3. Veillez à ce que la source utilise le groupe de champs qui contient le champ personnalisé AllFieldValues (voir Modification du groupe de champs utilisé par une source).

  4. Si ce n'est pas déjà fait, régénérez la source afin de peupler le champ AllFieldValues pour tous les documents de la source.

  5. Utilisez le Navigateur d'index afin d'évaluer les métadonnées disponibles (voir Évaluation des détails d'un document du Navigateur d'index).

Prochaines étapes?

Créez des champs personnalisés avec les métadonnées utiles, énumérées dans le champ AllFieldValues. Utilisez la valeur Field name comme nom de vos métadonnées (voir Ajout ou modification de champs personnalisés).